49567918f5
The time has come to migrate cacti.o.o from Ubuntu Precise and Ubuntu Trusty. Change-Id: Ia67ddb07baeaa19eaa47962d26ddba46a8fee6d3 Signed-off-by: Paul Belanger <pabelanger@redhat.com>
72 lines
1.9 KiB
Puppet
72 lines
1.9 KiB
Puppet
# Class to configure cacti on a node.
|
|
class openstack_project::cacti (
|
|
$sysadmins = [],
|
|
$cacti_hosts = [],
|
|
) {
|
|
|
|
if $::osfamily != 'Debian' {
|
|
fail("${::osfamily} is not supported.")
|
|
}
|
|
|
|
class { 'openstack_project::server':
|
|
iptables_public_tcp_ports => [80, 443],
|
|
sysadmins => $sysadmins,
|
|
}
|
|
|
|
class { '::apache':
|
|
mpm_module => 'prefork',
|
|
}
|
|
class { '::apache::mod::rewrite': }
|
|
class { '::apache::mod::php': }
|
|
|
|
package { 'cacti':
|
|
ensure => present,
|
|
}
|
|
|
|
::apache::vhost::custom { $::fqdn:
|
|
ensure => present,
|
|
content => template('openstack_project/cacti.vhost.erb'),
|
|
}
|
|
|
|
file { '/usr/local/share/cacti/resource/snmp_queries':
|
|
ensure => directory,
|
|
owner => 'root',
|
|
}
|
|
|
|
file { '/usr/local/share/cacti/resource/snmp_queries/net-snmp_devio.xml':
|
|
ensure => present,
|
|
source => 'puppet:///modules/openstack_project/cacti/net-snmp_devio.xml',
|
|
mode => '0644',
|
|
owner => 'root',
|
|
group => 'root',
|
|
require => File['/usr/local/share/cacti/resource/snmp_queries'],
|
|
}
|
|
|
|
file { '/var/lib/cacti/linux_host.xml':
|
|
ensure => present,
|
|
source => 'puppet:///modules/openstack_project/cacti/linux_host.xml',
|
|
mode => '0644',
|
|
owner => 'root',
|
|
group => 'root',
|
|
require => File[
|
|
'/usr/local/share/cacti/resource/snmp_queries/net-snmp_devio.xml'
|
|
],
|
|
}
|
|
|
|
file { '/usr/local/bin/create_graphs.sh':
|
|
ensure => present,
|
|
source => 'puppet:///modules/openstack_project/cacti/create_graphs.sh',
|
|
mode => '0744',
|
|
owner => 'root',
|
|
group => 'root',
|
|
}
|
|
|
|
exec { 'cacti_import_xml':
|
|
command => '/usr/bin/php -q /usr/share/cacti/cli/import_template.php --filename=/var/lib/cacti/linux_host.xml --with-template-rras',
|
|
cwd => '/usr/share/cacti/cli',
|
|
require => File['/var/lib/cacti/linux_host.xml'],
|
|
}
|
|
|
|
openstack_project::cacti_device { $cacti_hosts: }
|
|
}
|